/*
  Bak.HC
  Toby Betts
  Public domain.

  Like any other piece of software (and
  information generally), this software
  comes with NO WARRANTY.

  This is version 20250312 of Bak.HC.
*/

#include "Sha1.HC"

#define BACKUP_DIR "~/Backup"

U0 WriteNote(U8 *dir=NULL) {
  CDoc *cd;
  I64 i;
  U8 *buf;
  U8 *file;

  if (!dir) { return; }

  /* Create commit CDoc */
  cd=DocNew;
  DocFlagsToggle(cd,DOCF_PLAIN_TEXT|DOCF_NO_CURSOR);
  DocPrint(cd,
    "\n\n# Enter notes; comment ends at first '#'\n");

  /* Edit msg */
  DocEd(cd);

  /* Get the important lines */
  buf=DocSave(cd);
  DocDel(cd);
  i=StrFind("\n#",buf)-buf;
  if (!i) { return; }
  while (0x0A==buf[--i]) buf[i]=0;

  /* Write file */
  file=MStrPrint("%s/notes.TXT",dir);
  if (0<i) {
    FileWrite(file,buf,++i);
  }

  Free(buf);
  Free(file);
  return;
}

U8 *Bak(U8 *file_find_mask=NULL) {
  CDate cdt=Now;
  CDateStruct ds;
  CDirEntry *de,*tmpde;

  U8 *dst;
  U8 *sum;

  if (!file_find_mask) {
    "Bak: USAGE: Bak(\"filename\");\n";
    return 0;
  }

  tmpde=de=FilesFind(file_find_mask,FUF_JUST_FILES);
  if (!tmpde) {
    return 0;
  }

  Date2Struct(&ds,cdt);
  dst=MStrPrint(BACKUP_DIR "/%d%02d%02dT%02d%02d%02d",
    ds.year,ds.mon,ds.day_of_mon,
    ds.hour,ds.min,ds.sec
  );
  DirMk(BACKUP_DIR);
  DirMk(dst);
  WriteNote(dst);
  while (tmpde) {
    Copy(tmpde->full_name,dst);
    tmpde=tmpde->next;
  }
  DirEntryDel(de);

  sum=MStrPrint("%s/sha1sum.TXT",dst);
  Sha1Sum(dst,sum,FALSE);
  Free(sum);
  return dst;
}